Log In
Register
Home
February 28, 2017
Offline
Cell Ref > TAB, instead of typed TAB NAME?
File: DieselEditYearRef.xls
Tab: Total
Example: ROW 6, COLS: B-M & AL-BC
Formulas in Cells above quote '2020'! as tab.
However want to ref TAB NAME from Cell A6 not '2020'! but for info to compare with that TAB & CELL , the reason, so no INDIVIDUAL EDIT will be needed for Cols
B-M & AL-BC, for future year Rows.
B6 =IF(A6<=$BG$2,'2020'!$Y$29,"")
Hence for each YEAR ROW want to make it a copy & paste Row job instead of lots of editing.
Year tab is prepared template, same as 2021, just blank awaiting entries.
Cheers Stephan
See Answer
October 5, 2010
Offline
Hi Stephan,
You can use INDIRECT to reference the year in Column A, for example in D6 you could have
=INDIRECT(TEXT(A6,"yyyy")&"!$V$32")
So this way you only need to enter the year in ColA and the formulae in that row will pick up that year. But if you ever move the value you want out of cell V32 then this formula will break.
The ideal layout for data like this is a tabular format where everything is on 1 sheet. This does away with the issue you have where you have to update formula references as you create more sheets to store more data.
Regards
Phil
Answers Post
February 28, 2017
Offline
D6
=INDIRECT(TEXT(A6,"yyyy")&"!$V$32")
Thanks this worked for Columns B-L, few things:
1. If no data, how to change FALSE to nothing?
2. Columns AL-BC unable to construct working edit for A6 Ref instead of Direct Tab ref. A
lso these are ARRAY FORMULAS that require CTRL, SHIFT & ENTER:
Example in Cell AL6:
=MIN(IF(('2020'!$A$1:'2020'!$A$284="MPG"),('2020'!$B$1:'2020'!$B$284)))
Example in Cell AP6:
=MAX(IF(('2020'!$A$1:'2020'!$A$284="MPG"),('2020'!$B$1:'2020'!$B$284)))
Cheers
October 5, 2010
Offline
Hi Stephan,
The answers are:
1. Complete the IF statement by providing an answer if false, which is just an empty string "", so in C7
=IF(A7<=$BG$2,INDIRECT(TEXT($A7,"yyyy")&"!$Y$34"),"")
2. Use INDIRECT again, for example in AL6:
=MIN(IF(INDIRECT(TEXT($A6,"yyyy")&"!$A$1:$A$284")="MPG",INDIRECT(TEXT($A6,"yyyy")&"!$b$1:$b$284")))
I can tell that you've invested a lot of time into this workbook but unless you redo the layout into a tabular format you will keep coming up against issues like this and have to write monstrous formulae to get the data you want.
Regards
Phil
February 28, 2017
Offline
Many thanks Philip those suggestions worked!
1 other question: when answer is zero = 0, for these Calcs how to display blank space?
O7
=MIN(IF(A7<=$BG$2,IF(AL7:AO7>0,AL7:AO7,"")))
AL7 (ARRAY CALC)
=(MIN(IF(INDIRECT(TEXT($A7,"yyyy")&"!$A$1:$A$284")="MPG",INDIRECT(TEXT($A7,"yyyy")&"!$B$1:$B$284")))
Realise 1 non formula alternative:
Tools > Options > View > Zero Values
Did manage to make few working formulas of division on my own!:
BB6
=IF(INDIRECT(TEXT($A6,"yyyy")&"!$A$330")>0,INDIRECT(TEXT($A6,"yyyy")&"!$A$306")/INDIRECT(TEXT($A6,"yyyy")&"!$A$307"),"")
Also spreadsheet my approach is Data sheet then seperate Summary sheet.
I like this Dashboard approach, keeping all the individual data seperate from the summaries of it all, it may not be formula/speed efficient, but it is the only way I know! I need working examples to start with, I don't know formulas in my head, except something simple like IF or SUM Formula.
Also Slicers & other newer features may automate many aspects, but versions tried to use, just didn't work as intended, so in terms of Data Validation etc I just continue to use what I can get to work!
Time invested? It is good to be organised, & I realise many people don't have to be concerned about trivial things, so instead of having my time deliberately wasted it is nice to know what MILEAGE or MPG I did in a year, because years later it will all be forgotten.
Cheers
October 5, 2010
Offline
Hi Stephan,
You could wrap the function that produces a 0 in an IF and display an empty string
=IF(MIN(IF(A7<=$BG$2,IF(AL7:AO7>0,AL7:AO7,"")))=0,"",MIN(IF(A7<=$BG$2,IF(AL7:AO7>0,AL7:AO7,""))))
but a much easier way is to apply a custom number format to the cell(s) so that they don't display the 0
#,##0.00;-#,##0.00;;
I realise that reworking your data will take some considerable effort but the benefits in the long run would be simpler formulae and the ability to use tools like Pivot Tables and Power Query to get the insights you are after.
Regards
Phil
February 28, 2017
Offline
Thanks for those Formulas, workbook completed!
Appreciate new Excel features may save time, but older versions then 2016, seem to be less obvious with unobvious menus, and features that look simple but just don't work as intended like trying to drive a car away in neutral or pulling up to stop in gear. ...
Hence seperate tabs & totals with seperate summary page will be my approach, but yes some formulas to get desired calc sometimes feels like trying to make something simple into onerousity & time consuming.
February 28, 2017
Offline
So I know Autofilter suits my purposes often too!
But if the later functions actually work for me the individual, I doubt that.
But in that I know there is a bunch of empty Cells just waiting imminently for me, and colouring/shading cells is such a treat too.
1 Guest(s)
